DC Designs Concorde MobiFlight Events for the Autopilot

I’ve managed to extract all the autopilot events for the DCD Concorde. These are in the MobiFlight events.txt format and have all been tested in my sim.

//CONCORDE
CONC_AP_MASTER_TGL_1#(L:XMLVAR_Autopilot_1_Status) ! (>L:XMLVAR_Autopilot_1_Status) (L:XMLVAR_Autopilot_1_Status) (L:XMLVAR_Autopilot_2_Status) or (A:AUTOPILOT MASTER, Bool) != if{ (>K:AP_MASTER) (A:AUTOPILOT MASTER, Bool) ! if{ 0 (>L:XMLVAR_Autopilot_1_Status) (>H:Generic_Autopilot_1_Manual_Off) } }
CONC_AP_MASTER_TGL_2#(L:XMLVAR_Autopilot_2_Status) ! (>L:XMLVAR_Autopilot_2_Status) (L:XMLVAR_Autopilot_2_Status) (L:XMLVAR_Autopilot_1_Status) or (A:AUTOPILOT MASTER, Bool) != if{ (>K:AP_MASTER) (A:AUTOPILOT MASTER, Bool) ! if{ 0 (>L:XMLVAR_Autopilot_2_Status) (>H:Generic_Autopilot_2_Manual_Off) } }

CONC_AP_AT_ARM_1#(A:AUTOPILOT THROTTLE ARM:1, Bool) ! 1 (>K:AUTO_THROTTLE_ARM)
CONC_AP_AT_ARM_2#(A:AUTOPILOT THROTTLE ARM:2, Bool) ! 2 (>K:AUTO_THROTTLE_ARM)

CONC_FD_SLCT_1#(A:AUTOPILOT FLIGHT DIRECTOR ACTIVE:1, Bool) ! 1 (>K:TOGGLE_FLIGHT_DIRECTOR)
CONC_FD_SLCT_2#(A:AUTOPILOT FLIGHT DIRECTOR ACTIVE:2, Bool) ! 2 (>K:TOGGLE_FLIGHT_DIRECTOR)

CONC_HDG_BUG_INC#(L:HDG_AP_VALUE, Degrees) 1 + (>L:HDG_AP_VALUE)
CONC_HDG_BUG_DEC#(L:HDG_AP_VALUE, Degrees) 1 - (>L:HDG_AP_VALUE)

CONC_CRS_BUG_INC#(>K:VOR1_OBI_INC)
CONC_CRS_BUG_DEC#(>K:VOR1_OBI_DEC)

CONC_AP_ALT_INC#(L:ALT_AP_VALUE, feet) 60000 < if{ (L:ALT_TENS, number) 0 == if{ (L:ALT_AP_VALUE, feet) 1000 + (>L:ALT_AP_VALUE) } (L:ALT_TENS, number) 1 == if{ (L:ALT_AP_VALUE, feet) 100 + (>L:ALT_AP_VALUE) } (L:ALT_TENS, number) 2 == if{ (L:ALT_AP_VALUE, feet) 10 + (>L:ALT_AP_VALUE) } }
CONC_AP_ALT_DEC#(L:ALT_AP_VALUE, feet) 0 > if{ (L:ALT_TENS, number) 0 == if{ (L:ALT_AP_VALUE, feet) 1000 - (>L:ALT_AP_VALUE) } (L:ALT_TENS, number) 1 == if{ (L:ALT_AP_VALUE, feet) 100 - (>L:ALT_AP_VALUE) } (L:ALT_TENS, number) 2 == if{ (L:ALT_AP_VALUE, feet) 10 - (>L:ALT_AP_VALUE) } }

CONC_AP_SPD_INC#(L:IAS_AP_VALUE, Knots) 400 < if{ (L:IAS_TENS, Bool) ! if{ (L:IAS_AP_VALUE, Knots) 1 + (>L:IAS_AP_VALUE) } (L:IAS_TENS, Bool) if{ (L:IAS_AP_VALUE, Knots) 10 + (>L:IAS_AP_VALUE) } }
CONC_AP_SPD_DEC#(L:IAS_AP_VALUE, Knots) 0 > if{ (L:IAS_TENS, Bool) ! if{ (L:IAS_AP_VALUE, Knots) 1 - (>L:IAS_AP_VALUE) } (L:IAS_TENS, Bool) if{ (L:IAS_AP_VALUE, Knots) 10 - (>L:IAS_AP_VALUE) } }

CONC_RAD_INS_SW#(A:GPS DRIVES NAV1, Bool) ! (>K:TOGGLE_GPS_DRIVES_NAV1)

CONC_FD_SW_PILOT#(L:FD_Selector, Bool) ! (>L:FD_Selector)

CONC_BTN_AP_IAS_ACQ#(L:MAX CRUISE, Bool) if{ 0 (>L:MAX CRUISE) } (L:XMLVAR_AirSpeedIsInMach, Bool) if{ 0 (>L:XMLVAR_AirSpeedIsInMach) } (A:AUTOPILOT MANAGED SPEED IN MACH, Bool) if{ (>K:AP_MANAGED_SPEED_IN_MACH_OFF) } (A:AUTOPILOT THROTTLE ARM, Bool) if{ (L:IAS_ACQ, Bool) ! (>L:IAS_ACQ) } (L:IAS_ACQ, Bool) if{ (A:AUTOPILOT FLIGHT LEVEL CHANGE, Bool) ! if{ (>K:AP_AIRSPEED_ON) } (L:IAS_AP_VALUE, Knots) (>K:AP_SPD_VAR_SET) }

CONC_BTN_AP_ALT_HOLD#(L:ALT_ACQ, Bool) if{ 0 (>L:ALT_ACQ) } (L:MAX CLIMB, Bool) if{ 0 (>L:MAX CLIMB) } (L:MAX CRUISE, Bool) if{ 0 (>L:MAX CRUISE) } (>K:AP_ALT_HOLD)

CONC_BTN_AP_ALT_ACQ_B#(L:MAX CRUISE, Bool) if{ 0 (>L:MAX CRUISE) } (L:ALT_ACQ, Bool) ! (>L:ALT_ACQ) (L:ALT_ACQ, Bool) if{ (A:AUTOPILOT ALTITUDE LOCK, Bool) ! if{ (A:AUTOPILOT FLIGHT LEVEL CHANGE, Bool) ! if{ (>K:AP_ALT_HOLD_ON) } (L:ALT_AP_VALUE, feet) (>K:AP_ALT_VAR_SET_ENGLISH) } (A:AUTOPILOT ALTITUDE LOCK, Bool) if{ (L:ALT_AP_VALUE, feet) (>K:AP_ALT_VAR_SET_ENGLISH) } }

CONC_BTN_AP_SPD#(L:XMLVAR_AirSpeedIsInMach, Bool) if{ 0 (>L:XMLVAR_AirSpeedIsInMach) } (A:AUTOPILOT MANAGED SPEED IN MACH, Bool) if{ (>K:AP_MANAGED_SPEED_IN_MACH_OFF) } (L:IAS_ACQ, Bool) if{ 0 (>L:IAS_ACQ) } (L:MAX CRUISE, Bool) if{ 0 (>L:MAX CRUISE) 0 (>K:AP_AIRSPEED_SET) } (L:MAX CLIMB, Bool) ! (L:MAX CRUISE, Bool) ! & if{ (A:AUTOPILOT AIRSPEED HOLD, Bool) ! (>K:AP_AIRSPEED_SET) }

CONC_BTN_AP_MACH_HOLD#(L:XMLVAR_AirSpeedIsInMach, Bool) ! if{ 1 (>L:XMLVAR_AirSpeedIsInMach) } (A:AUTOPILOT MANAGED SPEED IN MACH, Bool) ! if{ (>K:AP_MANAGED_SPEED_IN_MACH_ON) } (L:IAS_ACQ, Bool) if{ 0 (>L:IAS_ACQ) } (L:MAX CLIMB, Bool) if{ 0 (>L:MAX CLIMB) 0 (>K:AP_MACH_SET) } (L:MAX CRUISE, Bool) if{ 0 (>L:MAX CRUISE) 0 (>K:AP_MACH_SET) } (A:AUTOPILOT MACH HOLD, Bool) ! (>K:AP_MACH_SET) (A:AUTOPILOT MACH HOLD, Bool) if{ (A:AIRSPEED MACH, Mach) (>AP_MACH_VAR_SET) }

CONC_BTN_AP_HDG#(A:AUTOPILOT HEADING LOCK, Bool) ! (>K:AP_HDG_HOLD)  (A:AUTOPILOT HEADING LOCK, Bool) if{ (A:PLANE HEADING DEGREES GYRO, Degrees) (>K:HEADING_BUG_SET) } (L:AP_PANEL_HEADING_HOLD, Bool) if{ 0 (>L:AP_PANEL_HEADING_HOLD) (A:AUTOPILOT HEADING LOCK, Bool) ! if{ (>K:AP_HDG_HOLD) } }

CONC_BTN_AP_MAX_CLIMB#(L:XMLVAR_AirSpeedIsInMach, Bool) if{ 0 (>L:XMLVAR_AirSpeedIsInMach) } (A:AUTOPILOT MANAGED SPEED IN MACH, Bool) if{ (>K:AP_MANAGED_SPEED_IN_MACH_OFF) } (L:MAX CRUISE, Bool) if{ 0 (>L:MAX CRUISE) } (L:MAX CLIMB, Bool) ! (>L:MAX CLIMB) (L:MAX CLIMB, Bool) if{ (A:AUTOPILOT FLIGHT LEVEL CHANGE, Bool) ! if{ (>K:FLIGHT_LEVEL_CHANGE) } 400 (>L:IAS_AP_VALUE) 400 (>K:AP_SPD_VAR_SET) } (L:MAX CLIMB, Bool) ! if{ (A:AIRSPEED INDICATED, Knots) 400 > if{ 400 (>K:AP_SPD_VAR_SET) 400 (>L:IAS_AP_VALUE) (L:ALT_AP_VALUE, feet) (>K:AP_ALT_VAR_SET_ENGLISH) } (A:AIRSPEED INDICATED, Knots) 400 < if{ (A:AIRSPEED INDICATED, Knots) (>L:IAS_AP_VALUE) (L:IAS_AP_VALUE, Knots) (>K:AP_SPD_VAR_SET) } }

CONC_BTN_AP_MAX_CRUISE#(L:MAX CLIMB, Bool) if{ 0 (>L:MAX CLIMB) } (L:MAX CRUISE, Bool) ! (>L:MAX CRUISE) (L:MAX CRUISE, Bool) ! if { (A:AUTOPILOT MACH HOLD, Bool) if{ (A:AIRSPEED MACH, Mach) (>AP_MACH_VAR_SET) } }

CONC_BTN_AP_VS#(A:AUTOPILOT VERTICAL HOLD, Bool) ! (>K:AP_VS_SET) (A:AUTOPILOT VERTICAL HOLD, Bool) if{ (A:VERTICAL SPEED, feet per minute) (>K:AP_VS_VAR_SET_ENGLISH) }

CONC_BTN_AP_VOR_LOC#(A:AUTOPILOT APPROACH HOLD, Bool) (A:AUTOPILOT GLIDESLOPE HOLD, Bool) and if{ (>K:AP_LOC_HOLD) } (>K:AP_LOC_HOLD)

CONC_BTN_AP_GLIDE#(A:AUTOPILOT APPROACH HOLD, Bool) (A:AUTOPILOT GLIDESLOPE HOLD, Bool) ! and if{ (>K:AP_APR_HOLD) } (>K:AP_APR_HOLD)

CONC_BTN_AP_LAND#(L:AUTOLAND, Bool) ! (>L:AUTOLAND, Bool) (L:AUTOLAND, Bool) if{ (A:AUTOPILOT MASTER, Bool) ! if{ (>K:AUTOPILOT_ON) 1 (>L:XMLVAR_Autopilot_1_Status) 1 (>L:XMLVAR_Autopilot_2_Status) } (A:AUTOPILOT APPROACH HOLD, Bool) (A:AUTOPILOT GLIDESLOPE HOLD, Bool) ! and if{ (>K:AP_APR_HOLD) } (>K:AP_APR_HOLD) (A:AUTOPILOT THROTTLE ARM, Bool) ! if{ (>K:AUTO_THROTTLE_ARM) } } }

//CONC_BTN_AP_GOARND	Evt: AUTO_THROTTLE_TO_GA	Var:AUTOPILOT TAKEOFF POWER ACTIVE
//CONC_BTN_AP_TURB		Evt:AP_WING_LEVELER			Var:AUTOPILOT WING LEVELER

CONC_BTN_AP_PITCH_HOLD#(L:ALT_ACQ, Bool) if{ 0 (>L:ALT_ACQ) } (A:AUTOPILOT ALTITUDE LOCK, Bool) if{ 0 (>K:AP_ALT_VAR_SET_ENGLISH) (>K:AP_ALT_HOLD_OFF) } (A:AUTOPILOT PITCH HOLD, Bool) ! (>K:AP_PITCH_LEVELER)

CONC_BTN_AP_IAS_HOLD#(L:XMLVAR_AirSpeedIsInMach, Bool) if{ 0 (>L:XMLVAR_AirSpeedIsInMach) } (A:AUTOPILOT MANAGED SPEED IN MACH, Bool) if{ (>K:AP_MANAGED_SPEED_IN_MACH_OFF) } (L:IAS_ACQ, Bool) if{ 0 (>L:IAS_ACQ) } (L:MAX CRUISE, Bool) if{ 0 (>L:MAX CRUISE) 0 (>K:AP_AIRSPEED_SET) } (L:MAX CLIMB, Bool) ! (L:MAX CRUISE, Bool) ! & if{ (A:AUTOPILOT AIRSPEED HOLD, Bool) ! (>K:AP_AIRSPEED_SET) }

CONC_BTN_AP_INS#(A:AUTOPILOT NAV1 LOCK, Bool) ! (>K:AP_NAV1_HOLD)

CONC_BTN_AP_TRK_HDG#(L:AP_PANEL_HEADING_HOLD, Bool) ! (>L:AP_PANEL_HEADING_HOLD) (L:AP_PANEL_HEADING_HOLD, Bool) if{ (A:AUTOPILOT HEADING LOCK, Bool) ! if{ (>K:AP_HDG_HOLD) } } (L:AP_PANEL_HEADING_HOLD, Bool) ! if{ (A:AUTOPILOT HEADING LOCK, Bool) if{ (>K:AP_HDG_HOLD) } }

//CONC_BTN_AP_BACKBEAM	Evt: AP_BC_HOLD				Var: AUTOPILOT BACKCOURSE HOLD

If you can, will you post to the Mobiflight HubHop page?

I tried to use the spreadsheet method to upload them but it was far too complicated and I don’t have the patience to enter them one by one - it was tedious enough just tracking them all down and testing them…